工作中，大家使用VLOOKUP函數(shù)查詢數(shù)據(jù)是很常見的事，但有時候，一個VLOOKUP函數(shù)可能無法解決更多的問題，這時候?qū)W習(xí)下其他函數(shù)組合也很必要！

下圖中，如果通過VLOOKUP函數(shù)查找E3:E5單元格姓名對應(yīng)的銷售額，公式應(yīng)該怎么寫？

F3公式：=VLOOKUP(E3,$B$3:$C$10,2,0)

公式解析：

=VLOOKUP(找什么，從哪里找，找到了返回什么，精確查找還是模糊查找）

E3：表示要查找的內(nèi)容。

$B$3:$C$10：表示以查找內(nèi)容為首列的查找區(qū)域。

2：表示我們要返回的結(jié)果在查找區(qū)域中屬于第2列。

0：表示精確查找。

可以代替VLOOKUP函數(shù)解決這道題的函數(shù)有哪些？

一、LOOKUP函數(shù)。

=LOOKUP(查找值，查找范圍，返回值范圍）

F3公式：=LOOKUP(1,0/($B$3:$B$10=E3),$C$3:$C$10)

公式解析：

$B$3:$B$10=E3：判斷B3:B10單元格區(qū)域中的內(nèi)容是否跟E3單元格內(nèi)容相等，若相等，返回TRUE，否則，返回FALSE，此時返回一個TRUE和FALSE的數(shù)組：{FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}

0/($B$3:$B$10=E3)：用0/TRUE，0/FALSE會返回一個0和錯誤值的數(shù)組：{#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;0;#DIV/0!;#DIV/0!;#DIV/0!}

整個公式的意思是：用LOOKUP函數(shù)查找數(shù)字1在{#DIV/0!;#DIV/0!;#DIV/0!;#DIV/0!;0;#DIV/0!;#DIV/0!;#DIV/0!}這個數(shù)組中的位置，但始終查不到，于是返回最后一個0值的位置，這時返回相對應(yīng)的C3:C10單元格區(qū)域中對應(yīng)的值。

二、INDEX+MATCH函數(shù)。

F3公式：=INDEX($C$3:$C$10,MATCH(E3,$B$3:$B$10,0))

公式解析：

=MATCH(查找對象，查找范圍，查找方式)

=INDEX(查找區(qū)域，返回所在行號，返回所在列號)

MATCH(E3,$B$3:$B$10,0)：精確查找E3單元格內(nèi)容在查找范圍B3:B10中的位置，返回的結(jié)果為：5。

$C$3:$C$10：是INDEX函數(shù)的查找區(qū)域。

整個公式的意思就是：在C3:C10查找區(qū)域內(nèi)，返回第5行對應(yīng)單元格的內(nèi)容。

三、OFFSET+MATCH函數(shù)。

F3公式：=OFFSET($B$2,MATCH(E3,$B$3:$B$10,0),1)

公式解析：精確查找E3單元格內(nèi)容在查找范圍B3:B10中的位置，返回的結(jié)果為：5。

=OFFSET(基準位置，向下或上偏移幾行，向右或左偏移幾列，引用區(qū)域的高度，引用區(qū)域的寬度）

MATCH(E3,$B$3:$B$10,0)：精確查找E3單元格內(nèi)容在查找范圍B3:B10中的位置，返回的結(jié)果為：5。

$B$2：是OFFSET函數(shù)的基準位置。

整個公式的意思是：以B2單元格為基準，向下偏移5行，向右偏移一行，最后兩個參數(shù)省略，默認一個單元格的高度。即C7單元格的位置。

四、INDIRECT+MATCH函數(shù)。

F3公式：=INDIRECT('C'&MATCH(E3,$B$2:$B$10,0)+1)

公式解析;

=INDIRECT(引用區(qū)域，引用格式）

MATCH(E3,$B$2:$B$10,0)：精確查找E3單元格內(nèi)容在查找范圍B3:B10中的位置，返回的結(jié)果為：6。

MATCH(E3,$B$2:$B$10,0)+1：加1是因為單元格的內(nèi)容是從第2行開始寫的，而行號從1開始，加1才能得到正確的結(jié)果，這里返回的結(jié)果為：7。

=INDIRECT('C'&MATCH(E3,$B$2:$B$10,0)+1)：使用&文本連接符將C與MATCH函數(shù)返回的位置連接起來，相當于公式=INDIRECT('C7')，也就是引用C7單元格的內(nèi)容，所以結(jié)果為：195。

五、HLOOKUP+TRANSPOSE函數(shù)。

=HLOOKUP(查找值，查找區(qū)域，返回第幾行的數(shù)據(jù)，精確查找還是近似查找)

=TRANSPOSE(需要進行轉(zhuǎn)置的數(shù)組或工作表上的單元格區(qū)域)

F3公式：{=HLOOKUP(E3,TRANSPOSE($B$3:$C$10),2,0)}

公式解析：

TRANSPOSE($B$3:$C$10)：將縱向的單元格區(qū)域B3:C10轉(zhuǎn)成橫向的單元格數(shù)據(jù)。使用該函數(shù)的原因是因為HLOOKUP函數(shù)只能橫向查找。

{=HLOOKUP(E3,TRANSPOSE($B$3:$C$10),2,0)}：

E3：查找值。

TRANSPOSE($B$3:$C$10)：查找區(qū)域。

2：返回值在查找區(qū)域的第2行。

0：精確查找。

注意：該公式中的雙大花括號并不是手動輸入的，而是公式寫完之后按組合鍵“Ctrl+Shift+Enter”自動生成的。